# Gnuplot script
# plot relative timings for 80-bit/32-bit/64-bit
reset
set macros
#set term png enhanced font arial 10 size 400,600
set term png enhanced size 300,400 font arial 10

set xlabel "N"
set key left top Left reverse
set xrange [2**20 : 2**35]
set yrange [0.5:2.2]
set logscale x
# set logscale y
er(x,y)=sqrt(x**2+y**2)

set grid

#### 80-bit vs. 64-bit vs. 32-bit

#colors="black   red       blue      green       dark-violet  grey40  yellow"
#colors="black   yellow4   brown4    brown     dark-violet blue dark-blue green"

# reset index of default line styles
colors="blue  green  red  dark-violet brown yellow"
set for [i=1:words(colors)] linetype i lw 2 lc rgb word(colors, i) 

dir="./data2/"
#dir="./"
tlist="SUM E PI"
caps='S E PI'
plist="32 64"
#hosts=  "chromebook"
hosts=  "cluster cluster52 cluster51 cluster42 rut chromebook"
#ext=".o2"
#ext=".o2native"

do for [ext in ".o2 .o2native"] {
do for [p in plist] {
#####
do for [h in hosts] {
do for [t in tlist] {
f=h."_".t.ext
system( sprintf("cd %s; paste %s_%s 80_%s > %s.tmp",dir,p,f,f,f) )
} 
#####
set title sprintf("Performance 80-bit over %s-bit",p)
set output sprintf('%s_80_%s.png',h,p.ext)
#plot for [i=1:words(tlist)] dir.h."_".word(tlist,i).ext.".tmp" using ($2>2**22 ? $2 : 1/0):($5/$15) title h." ".word(caps,i) with lp 
plot for [i=1:words(tlist)] dir.h."_".word(tlist,i).ext.".tmp" using 2:($5/$15) title h." ".word(caps,i) with lp 
} #end h loop
} #end of rprec loop
}