# Gnuplot script
# plot relative timings for 80-bit/32-bit/64-bit
reset
set macros
#set term png enhanced font arial 10 size 400,600
set term png enhanced size 700,500
eps=0.2
set xlabel "N"
set key right top Left reverse
set xrange [2**9 : 2**37]
#set yrange [-eps:18]
set logscale x
set logscale y
#er(x,y)=sqrt(x**2+y**2)

#set grid

dir="./data/"
#dir="./"

do for [h in "cluster cluster42"] {
#print sprintf("cd %s; paste 32_%s_sum.o2.1 64_%s_sum.o2.1 80_%s_sum.o2.1 > %s.tmp",dir,h,h,h,h)
system( sprintf("cd %s; paste 32_%s_e.o2.1 64_%s_e.o2.1 80_%s_e.o2.1 > %s.tmp",dir,h,h,h,h) ) 
}
# reset index of default line styles
colors="black    blue      green     dark-violet red   yellow      brown"
set for [i=1:words(colors)] linetype i lw 2 lc rgb word(colors, i) 

ref=2.71828182845904523536029

set title sprintf("Relative accuracy of E")
set output sprintf('acc_e.png')

h="cluster42"; dat=dir.h.".tmp"
plot dat using 2:($2 <= 2**19 ? abs($4-ref)/ref : 1/0) title "32-bit" with lp,\
     dat using 2:(abs($11-ref)/ref) title "64-bit" with lp,\
     dat using 2:(abs($18-ref)/ref) title "80-bit" with lp

#set title sprintf("Relative accuracy of E (parallel)")
#set output sprintf('acc_e_para.png')
#plot dat using 2:(abs($6-ref)/ref) title "32-bit" with lp,\
#     dat using 2:(abs($13-ref)/ref) title "64-bit" with lp,\
#     dat using 2:(abs($20-ref)/ref) title "80-bit" with lp